Continuing the discussion from Working MIMOlite Device Type with Sensor:
I integrated my doorbell today using a MIMOlite with the device type linked above. I have a dog who loves to bark at the front door whenever the doorbell rings, so I’d really rather get a push notification and have enough time to get her leash on, and then calmly go answer the door. If I don’t hear my phone, I still want the doorbell to ring on repeated presses.
So I wrote this SmartApp. Perhaps it will be helpful to others. It can be easily modified to use other hardware.
I’ll add pictures of the wiring sometime soon…
First, disconnect the wire that leads from your doorbell button to the doorbell transformer and the wire that leads from your doorbell button to the doorbell chime, and connect those to the contact input on the MIMOlite.
Second, connect the NO and COM ports of the MIMOlite to the doorbell transformer and the doorbell chime, respectively.
Third, plug in the MIMOlite, and include it in your network.
Fourth, set the device type for the MIMOlite to use the above device to give it the capabilities “Contact Sensor” and “Momentary”. Set the delay of the momentary switch to something that works for you… I’m using 500ms.
Fifth, install the SmartApp:
/**
* Sometimes Silent Doorbell
*
* Copyright 2015 Paul Toben
*
* Licensed under the Apache License, Version 2.0 (the "License"); you may not use this file except
* in compliance with the License. You may obtain a copy of the License at:
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software distributed under the License is distributed
* on an "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the License
* for the specific language governing permissions and limitations under the License.
*
*
*
*
* This app is designed to work with the MIMOlite using a device type that exposes the input relay as a contact
* sensor, and the output relay as a momentary switch (using the Momentary capability). To find a device type
* for your MIMOlite, see: https://community.smartthings.com/t/working-mimolite-device-type-with-sensor/1468/4
*
* You must modify the linked device type with a momentary delay that works for your dorbell. I am using 500ms.
*
* This app can, however, be used with any contact sensor as an input and any momentary switch as an output. YMMV.
*
*/
definition(
name: "Sometimes Silent Doorbell",
namespace: "",
author: "Paul Toben",
description: "A doorbell controller that first sends a push notification, and only rings the doorbell after some delay. Great for people with sleeping children or reactive dogs.",
category: "My Apps",
iconUrl: "https://s3.amazonaws.com/smartapp-icons/Convenience/Cat-Convenience.png",
iconX2Url: "https://s3.amazonaws.com/smartapp-icons/Convenience/Cat-Convenience@2x.png",
iconX3Url: "https://s3.amazonaws.com/smartapp-icons/Convenience/Cat-Convenience@2x.png")
preferences {
section ("When this doorbell button is pushed...") {
input "contact1", "capability.contactSensor", title: "Button", multiple: false, required: true
}
section ("Send this message") {
input "message", "text", title: "Notification message", description: "Doorbell!", required: true
}
section ("Ring this doorbell...") {
input "switch1", "capability.momentary", title: "Momentary Switch", multiple: false, required: true
}
section("But only allow the bell to ring after how many seconds?") {
input "silentSeconds", "decimal", title: "Seconds", required: true
}
section("Reset to silent mode after how many minutes?") {
input "resetMinutes", "decimal", title: "Minutes", required: true
}
}
def installed() {
log.debug "Installed with settings: ${settings}"
initialize()
}
def updated() {
log.debug "Updated with settings: ${settings}"
unsubscribe()
initialize()
}
def initialize() {
subscribe(contact1, "contact.closed", contactClosedHandler)
unschedule(stateReset)
state.running = false
log.debug "Initialized, reset scheduled calls, and state.running is ${state.running}"
}
def contactClosedHandler(evt) {
log.debug "Doorbell button push detected"
runIn(resetMinutes * 60, stateReset) //schedule the reset back to silent mode
if (state.running == false) { //if this is the first press of the button,
state.running = true //mark that the button has been pressed recently
state.firstPush = now() //mark the time that the button was pressed this first time
log.debug "state.firstPush is: ${state.firstPush}"
silentBell() //call silentBell to send a push notification.
}
else { //if this is NOT the first press of the button
def millisSinceFirst = now() - state.firstPush //calculate how long ago the first press was
log.debug "seconds since first push is ${millisSinceFirst / 1000}"
if (millisSinceFirst <= (silentSeconds * 1000)) { //if this press should still be silent,
log.debug "Not enough time has passed. silentSeconds is greater. calling silentBell"
silentBell() //call silentBell to send a push notification.
}
else if (millisSinceFirst > (silentSeconds * 1000)){ //if this press should be loud,
log.debug "millisSinceFirst is greater, calling loudBell"
loudBell() //call loudBell and ring my bell l l, ring my bell.
}
}
}
def silentBell() { //method for sending push notifications when the button is pushed
log.debug "silentBell called, sending push message"
sendPush(message)
}
def loudBell() { //method for ringing the doorbell
log.debug "loudBell called... Ding Dong."
switch1.push
}
def stateReset() { //method for resetting to silent mode
state.running = false
log.debug "stateReset called. state.running is now: ${state.running}"
}